Redigerer REXX (avsnitt)

== Prosedyrer ==
En prosedyre er i Rexx en navngitt programsnutt som kan utføre en oppgave, og som kan kalles en eller flere ganger fra den resterende programkoden. Rexx skiller mellom interne og eksterne prosedyrer. 

=== Interne prosedyrer ===
En intern prosedyre er en som er definert i samme programfil som den blir kalt fra, mens en ekstern prosedyre er definert i sin egen programfil.

Her er et eksempel på bruk av en intern prosedyre:
 say half(16)
 say half(6.8)
 exit
 
 half:
    parse arg num
    return "Halvparten av" num "er" num/2

=== Eksterne prosedyrer ===
Vi kan lage det samme programmet som over med en ekstern funksjon i stedet. Først hovedprogrammet:
 say half(16)
 say half(6.8)
 exit

I en separat fil som vi kaller ''half.rexx'' har vi følgende:
 parse arg num
 return "Halvparten av" num "er" num/2

Resultatet av de to programmene skal være det samme.

Når et program kaller en prosedyre vil Rexx først se om det finnes en prosedyre med samme navn i den kjørende programfilen. Dersom det ikke gjør det vil den lete etter en egen fil som har det navnet til prosedyren. Regler for hvilke etternavn, og om store bokstaver er viktige eller ikke er noe opp til implementasjonen.

=== Lokale variabler ===
Når man definerer en intern prosedyre som over, vil prosedyren i utgangspunktet ha tilgang til alle varable som er i bruk i programmet. Ofte ønsker vi å benytte lokale variable i en prosedyre, og begrense tilgangen til varable utenfor. Dette kan vi gjøre med ''procedure''-kommandoen.

 a = 4
 b = "Nils"
 call baklengs
 say c
 exit
 
 baklengs:
     procedure expose b
     say a
     say reverse(b)
     c = 5
     return

Prosedyren ''baklengs'' har her to lokale variable ''a'' og ''c'', mens den har blitt gitt tilgang til den globale ''b''. Resultatet av å kjøre dette programmet vises nedenfor.

 A
 sliN
 C

Vi ser at prosedyren skriver ut ''A'' i stedet for verdien av variablene ''a'' siden denne ikke er definert i prosedyren. Verdien av ''c'' er på samme måte ikke synlig utenfor prosedyren hvor den er definert. Variabelen ''b'' har dermed blitt gjort synlig via ''expose''-kommandoen, så prosedyren har full tilgang til den.

''Expose''-kommandoen gir en prosedyre tilgang til variable som er tilgjengelige der hvor prosedyren blir kalt fra. Rexx har ikke noe globalt skop for variable, så om ikke variabelen ikke er tilgjengelig der en prosedyre blir kalt fra så finnes det ingen måte å gi prosedyren tilgang til variabelen heller.

Programmet nedenfor vil kanskje ikke gi helt det resultatet man ville forvente:
 a = "Geir"
 b = "Nils"
 call forlengs_baklengs
 exit
 
 forlengs_baklengs:
    procedure expose a
    say a
    call baklengs
    return
 
 baklengs:
     procedure expose b
     say reverse(b)
     return

Resultat:
 Geir
 B

Hvis man derimot i prosedyren ''forlengs_baklengs'' satte inn:
 procedure expose a b

Så ville resultatet bli mer som forventet:
 Geir
 sliN